Gold Fish 3/goldfish_volume_3.bin/files/util/cdity/cliphistory/install/install cliphistory

Text File | 1994-09-15 | 13KB | 544 lines

; == English strings =========================================================

(set default-lang 4)

(set #bad-kick "You must be using Kickstart 2.04+ to install ClipHistory")

(set #install-msg
  (cat
    "\n\nWelcome to the ClipHistory installation utility.\n\n"
    "This program lets you install ClipHistory on your Amiga.\n\n"
    "See the manual for more information about ClipHistory.\n\n"
    "ClipHistory  © 1994  Magnus Holmgren."
  )
)

(set #welcome "Welcome to the ClipHistory installer utility.")

(set #copying "Copying ")

(set #were-cliphistory
  (cat
    "Where would you like to install ClipHistory?"
  )
)

(set #help-were-cliphistory
  (cat
    "    If you place ClipHistory in Sys:WBStartup, it will automatically "
    "be started each time you start your Amiga."
  )
)

(set #copy-icon "Should the icon be copied as well?")

(set #help-copy-icon
  (cat
    "    Since you already have ClipHistory installed, copying the icon "
    "will mean that the current settings are lost. However, there may "
    "be some new tooltypes in this version, so if you don't copy the icon "
    "I suggest you read the version history carefully."
  )
)

(set #install-cliphistory-guide
  "Would you like to install ClipHistory.guide?"
)

(set #were-cliphistory-guide
  "Where would you like to install ClipHistory.guide?"
)

(set #help-were-reqchange-guide
  (cat
    "    ClipHistory.guide is the manual for ClipHistory in the special "
    "AmigaGuide® hypertext format. You need a program like AmigaGuide or "
    "MultiView to view it properly."
  )
)

(set #install-cliphistory-man
  "Would you like to install ClipHistory.man?"
)

(set #were-cliphistory-man
  "Where would you like to install ClipHistory.man?"
)

(set #help-were-reqchange-man
  (cat
    "    ClipHistory.man is the manual for ClipHistory in normal text "
    "format, suitable for any More-like program. If you already have "
    "installed ClipHistory.guide then you'll probably have no need for this "
    "file."
  )
)

(set #which-language "\nWhich languages should be installed?")

(set #which-language-help
  (cat
    "    The Amiga can be operated in many different languages. If you "
    "want ClipHistory to use the same language as the Amiga Workbench "
    "then a catalog file must be copied to your harddisk for each "
    "language supported.\n"
    "    To reduce the amount of space consumed by the language files, "
    "you can select to have only the files of specific languages "
    "copied.\n"
    "    Simply check the boxes of the languages you wish to have "
    "available on your system.\n"
    "    Please note that there are not language files for all listed "
    "languages."
  )
)

; == =========================================================

(if (= @language "dansk" )
  (
    (set default-lang 2)
  )
)

; == German strings =========================================================

(if (= @language "deutsch")
  (
    (set default-lang 1)
  )
)

; == =========================================================

(if (= @language "español")
  (
    (set default-lang 8)
  )
)

; == =========================================================
(if (= @language "français")
  (
    (set default-lang 16)

    (set #bad-kick "Vous devez utiliser le Kickstart 2.04+ pour installer ClipHistory")

    (set #install-msg
      (cat
        "\n\nBienvenue dans le systême d'installation de ClipHistory.\n\n"
        "Ce programme vous permet d'installer ClipHistory sur votre Amiga.\n\n"
        "Reportez-vous au manuel pour plus d'informations sur ClipHistory.\n\n"
        "ClipHistory  © 1994  Magnus Holmgren."
      )
    )

    (set #welcome "Bienvenue dans le systême d'installation de ClipHistory.")

    (set #copying "Copie de ")

    (set #were-cliphistory "Où désirez-vous installer ClipHistory ?")

    (set #help-were-cliphistory
      (cat
        "    Si vous placez ClipHistory dans Sys:WBStartup, il sera automatiquement "
        "lancé à chaque fois que vous démarrerez votre Amiga."
      )
    )

    (set #install-cliphistory-guide
      "Desirez-vous installer ClipHistory.guide ?"
    )

    (set #were-cliphistory-guide
      "Où desirez-vous installer ClipHistory.guide ?"
    )

    (set #help-were-reqchange-guide
      (cat
        "    ClipHistory.guide est le manuel pour ClipHistory dans le format "
        "special AmigaGuide® hypertexte. Vous necessitez un programme comme  "
        "AmigaGuide ou MultiView pour le voir correctement."
      )
    )

    (set #install-cliphistory-man
      "Desirez-vous installer ClipHistory.man ?"
    )

    (set #were-cliphistory-man
      "Où desirez-vous installer ClipHistory.man ?"
    )

    (set #help-were-reqchange-man
      (cat
        "    ClipHistory.man est le manuel pour ClipHistory dans le format "
        "noraml, utilisable par n'importe quel programme comme More. Si vous "
        "avez déjà installé ClipHistory.guide vous n'aurez probablement pas "
        "utilité de ce fichier."
      )
    )

    (set #which-language "\nQuelles langues doivent être installées ?")

    (set #which-language-help
      (cat
        "    L'Amiga peut être utilisé dans beaucoup de langues différentes "
        "Si vous voulez que ClipHistory utilise la même langue que votre "
        "Workbench Amiga un fichier catalogue doit être copié dans votre "
        "disque dur pour chaque langue supportée.\n "
        "    Pour réduire l'espace consommé par les fichiers de langue, "
        "vous pouvez choisir de ne copier que les fichiers spécifiques à "
        "certaines langues.\n"
        "    Cochez simplement les cases des langues que vous souhaitez "
        "avoir disponibles dans votre systême.\n"
        "    Notez qu'il n'y a pas de fichiers de langue pour toutes les "
        "langues listées."
      )
    )
  )
)

; == =========================================================

(if (= @language "italiano")
  (
    (set default-lang 32)
  )
)

; == =========================================================

(if (= @language "nederlands")
  (
    (set default-lang 64)
  )
)

; == =========================================================

(if (= @language "norsk")
  (
    (set default-lang 128)
  )
)

; == =========================================================

(if (= @language "português")
  (
    (set default-lang 256)
  )
)

; == =========================================================

(if (= @language "suomi")
  (
    (set default-lang 512)
  )
)

; == Swedish strings =========================================================

(if (= @language "svenska")
  (
    (set default-lang 1024)

    (set #bad-kick
      "Du måste använda Kickstart 2.04+ för att installera ClipHistory"
    )

    (set #install-msg
      (cat
        "\n\nVälkommen till Installeraren.\n\n"
        "Det här programmet låter dig installera ClipHistory i din Amiga.\n\n"
        "Se manualen för information om hur ClipHistory får distribueras."
      )
    )

    (set #welcome "Välkommen till installeraren för ClipHistory.")

    (set #copying "Kopierar ")

    (set #were-cliphistory "Var vill du placera ClipHistory?")

    (set #help-were-cliphistory
      (cat
        "  Om du placerar ClipHistory i Sys:WBStartup, så kommer programmet "
        "automatiskt att startas varje gång du startar din Amiga."
      )
    )

    (set #copy-icon "Ska symbolen också kopieras?")

    (set #help-copy-icon
      (cat
        "  Eftersom du redan har ClipHistory installerad, så skulle en kopiering "
        "av symbolen göra att de aktuella inställningarna försvinner. Tänk på att "
        "det kan finnas några nya verktygstyper i den här versionen, så om du "
        "inte kopierar symbolen så rekommendrar jag att du läser igenom "
        "versionshistorian ordentligt."
      )
    )

    (set #install-cliphistory-guide "Vill du installera ClipHistory.guide?")

    (set #were-cliphistory-guide "Var vill du placera ClipHistory.guide?")

    (set #help-were-cliphistory-guide
      (cat
        "  ClipHistory.guide är manualen till ClipHistory i AmigaGuides "
        "speciella hypertextformat. Du behöver ett program som AmigaGuide "
        "eller MultiView för att se den ordentligt."
      )
    )

    (set #install-cliphistory-man "Vill du installera ClipHistory.man?")

    (set #were-cliphistory-man "Var vill du placera ClipHistory.man?")

    (set #help-were-cliphistory-man
      (cat
        "  ClipHistory.man är manualen till ClipHistory i vanligt textformat, "
        "lämplig för vilket More-liknande program som helst. Har du redan "
        "installerat ClipHistory.guide så behöver du förmodligen inte "
        "installera den här filen."
      )
    )

    (set #which-language "\nVilka språk vill du installera?")

    (set #which-language-help
      (cat
        "  Amigan kan arbeta med flera olika språk. Om du vill att "
        "ClipHistory ska använda samma språk som Amiga Workbench så "
        "måste en så kallad katalogfil kopieras till din systemdisk "
        "för varje språk.\n"
        "  För att minimera diskutrymmet för språkfiler kan du välja "
        "att bara installera filerna för vissa språk.\n"
        "  Markera bara rutorna för de språk du önskar installera i "
        "din dator."
        "  Obs: Det finns inte språkfiler för alla visade språk."
      )
    )
  )
)

; ============================================================================

; Copy the info file _info to destination, using the MagicWB version,
; if MagicWB 2.0+ is installed.
(procedure mycopyinfo
  (
    (if (= 1 (exists "Env:MagicWB" (noreq)))
      (set infofile (tackon "/MagicWB/" (fileonly _info)))
      (set infofile _info)
    )

    (copyfiles
      (source infofile)
      (dest   destination)
    )
  )
)

(set @default-dest "")

; Check Kickstart version. Exit if not at least 2.0

(if (< (/ (getversion) 65536) 37)
  (abort #bad-kick)
)

(message #install-msg)

(welcome)

; Copy ClipHistory

(set destination
  (askdir
    (prompt  #were-cliphistory)
    (help    (cat #help-were-cliphistory "\n\n" @askdir-help))
    (default "Sys:WBStartup")
  )
)

(copylib
  (prompt (cat #copying "ClipHistory..."))
  (source "/ClipHistory")
  (dest   destination)
)

(if (= 1 (exists (tackon destination "ClipHistory.info") (noreq)))
  (if
    (askbool
      (prompt #copy-icon)
      (help   #help-copy-icon)
    )

    (
      (set _info "/ClipHistory.info")
      (mycopyinfo)
    )
  )

  (
    (set _info "/ClipHistory.info")
    (mycopyinfo)
  )
)

(complete 25)

; Copy ClipHistory.guide

(if
  (askbool
    (prompt (cat "\n" #install-cliphistory-guide))
    (help   #help-were-cliphistory-guide)
  )

  (
    (set destination
      (askdir
        (prompt  #were-cliphistory-guide)
        (help    (cat #help-were-cliphistory-guide "\n\n" @askdir-help))
        (default "Work:")
      )
    )

    (copyfiles
      (prompt (cat #copying "ClipHistory.guide..."))
      (source "/ClipHistory.guide")
      (dest   destination)
    )

    (set _info "/ClipHistory.guide.info")
    (mycopyinfo)

    ; Modify tooltypes of ClipHistory.guide if this is needed

    (if (< (/ (getversion) 65536) 39)
      (tooltype
        (dest (tackon destination "ClipHistory.guide"))
        (setdefaulttool "AmigaGuide")
      )
    )
  )
)

(complete 50)

; Copy ClipHistory.man

(if
  (askbool
    (prompt (cat "\n" #install-cliphistory-man))
    (help   #help-were-cliphistory-man)
  )

  (
    (set destination
      (askdir
        (prompt  #were-cliphistory-man)
        (help    (cat #help-were-cliphistory-man "\n\n" @askdir-help))
        (default "Work:")
      )
    )

    (copyfiles
      (prompt (cat #copying "ClipHistory.man..."))
      (source "/ClipHistory.man")
      (dest   destination)
      (infos)
    )

    (set _info "/ClipHistory.man.info")
    (mycopyinfo)
  )
)

(complete 75)

; Copy catalog files

(if (= (exists "Locale:") 2)
  (
    (set lang
      (askoptions
        (prompt #which-language)
        (help   (cat #which-language-help "\n\n" @askoptions-help))
        (choices
          "Dansk"
          "Deutch"
          "English"
          "Español"
          "Français"
          "Italiano"
          "Nederlands"
          "Norsk"
          "Português"
          "Suomi"
          "Svenska"
        )
        (default default-lang)
      )
    )


    (set n 0)

    (while
      (set language
        (select n
          "Dansk"
          "Deutch"
          "English"
          "Español"
          "Français"
          "Italiano"
          "Nederlands"
          "Norsk"
          "Português"
          "Suomi"
          "Svenska"
          ""
        )
      )

      (
        (if (IN lang n)
          (if (<> 2 n)   ; No catalog for english strings...
            (
              (set catalogs (tackon "/Catalogs" language))

              (set catsource (tackon catalogs "cliphistory.catalog"))

              (set destination (tackon "Locale:Catalogs" language))

              (if (exists catsource)
                (
                  (makedir destination)

                  (copylib
                    (source catsource)
                    (dest destination)
                  )
                )
              )
            )
          )
        )

        (set n (+ n 1))
      )
    )
  )
)

(complete 100)

; End of Installer script